How to create an icon on your desktop to update wire

[SuperLlama]

TortoiseProc.exe /command:update /path:"C:\Program Files (x86)\Steam\steamapps\[STEAM ACCOUNT NAME HERE]\garrysmod\garrysmod\addons\Adv Duplicator" /closeonend:1

This only works on 64-bit machines, older machines don't have (x86) - unless, of course, tortoise notices and cuts it out. I tried to open that folder with Run and it said "you noob wut are Program"

[mattwd0526]

I made an icon for this, if anybody wants:

wiremod.ico

Picture:

[Ehmmett]

Mine just starts at C:/ then it says skipped all the way down to each addon folder and doesn't actually update anything? I copy pasted your code, what am I doing wrong?

Notes:
Using WinXP, TortoiseSVN, and all the folders are named correctly in the .bat (All the way down to case sensitive)

[Donkie]

Mine just starts at C:/ then it says skipped all the way down to each addon folder and doesn't actually update anything? I copy pasted your code, what am I doing wrong?

Notes:
Using WinXP, TortoiseSVN, and all the folders are named correctly in the .bat (All the way down to case sensitive)

Did you try my code?

@echo off
echo Updating gmod SVN repositories...
echo Updating Wire
start TortoiseProc.exe /command:update /path:"c:\Program\Steam\steamapps\[Steamname]\garrysmod\garrysmod\addons\wire" /notempfile /closeonend:1
echo Updating Wire model pack
start TortoiseProc.exe /command:update /path:"c:\Program\Steam\steamapps\[Steamname]\garrysmod\garrysmod\addons\wire model pack 1" /notempfile /closeonend:1
echo Updating Advance Duplicator
start TortoiseProc.exe /command:update /path:"c:\Program\Steam\steamapps\[Steamname]\garrysmod\garrysmod\addons\Adv Duplicator" /notempfile /closeonend:1
echo Updating PHX
start TortoiseProc.exe /command:update /path:"c:\Program\Steam\steamapps\[Steamname]\garrysmod\garrysmod\addons\phx3" /notempfile /closeonend:1
echo Updating Wire extras
start TortoiseProc.exe /command:update /path:"c:\Program\Steam\steamapps\[Steamname]\garrysmod\garrysmod\addons\wire extras" /notempfile /closeonend:1
echo Update done!
echo Do you want to start Garrysmod? (Y/N) 
set/p "cho=>" 
if %cho%==Y goto START
if %cho%==y goto START 
if %cho%==n goto END 
if %cho%==N goto END 
:START
start "mm" "C:\Program Files\Steam\steamapps\[Steamname]\garrysmod\hl2.exe" -game garrysmod +exec "gameinfo.txt" -console
:END
exit

[Ehmmett]

Did you try my code? *code*

Yes I did.

It opens tortoise svn fine. But for some reason it just lists folders and says "skipping" and then finishes without updating anything.

[Hobo]

That usually means the wrong path, check the batch file paths and then make sure it's the same as YOUR paths.

[Ehmmett]

That usually means the wrong path, check the batch file paths and then make sure it's the same as YOUR paths.

If you had read my post, you would have seen that I said I already did.

[SuperLlama]

Allow me to fix it:

@echo off
IF NOT EXIST "C:\Program Files (x86)" GOTO 32BIT
set APPS=C:\Program Files (x86)\Steam\SteamApps
goto decided
:32BIT
set APPS=C:\Program Files\Steam\SteamApps
:decided
set /P USER="Enter your steam username> "
echo Updating gmod SVN repositories...
echo Updating Wire
start TortoiseProc.exe /command:update /path:"%APPS%\%USER%\garrysmod\garrysmod\addons\wire" /notempfile /closeonend:1
echo Updating Wire model pack
start TortoiseProc.exe /command:update /path:"%APPS%\%USER%\garrysmod\garrysmod\addons\wire model pack 1" /notempfile /closeonend:1
echo Updating Advance Duplicator
start TortoiseProc.exe /command:update /path:"%APPS%\%USER%\garrysmod\garrysmod\addons\Adv Duplicator" /notempfile /closeonend:1
echo Updating PHX
start TortoiseProc.exe /command:update /path:"%APPS%\%USER%\garrysmod\garrysmod\addons\phx3" /notempfile /closeonend:1
echo Updating Wire extras
start TortoiseProc.exe /command:update /path:"%APPS%\%USER%\garrysmod\garrysmod\addons\wire extras" /notempfile /closeonend:1
echo Update done!
echo Do you want to start Garrysmod? (Y/N) 
set/p "cho=>" 
if %cho%==Y goto START
if %cho%==y goto START 
if %cho%==n goto END 
if %cho%==N goto END 
:START
start "mm" "%APPS%\%USER%\garrysmod\hl2.exe" -game garrysmod +exec "gameinfo.txt" -console
:END
exit

This script requires no editing. Just run it, it adapts to (x86) if needed and asks you for your username.

[a_p3rson]

Damn. I have been outed by batch wizzards.

I am ashamed of my self.

lol thx good job guys

[-HP-]

@echo off
ECHO Garrys Mod SVN Updater
ECHO By -HP-
ECHO.

REM *** Add steam path down to username here ***
CD C:\Program Files\Steam\steamapps\[username]

:start
set /P choice="Hit 1 for TortoiseSVN, 2 for normal command line SVN: "
IF "%choice%"=="1" GOTO tortoise
IF "%choice%"=="2" GOTO svn
ECHO Invalid choice, nub
ECHO.
GOTO start

:svn
FOR /D %%G IN (garrysmod\garrysmod\addons\*) DO ( if EXIST "%%G\info.txt" ( if EXIST "%%G\.svn\*" (
	ECHO.
	ECHO Updating %%G
	svn up "%%G"
) ) )
FOR /D %%G IN (garrysmod\garrysmod\gamemodes\*) DO ( if EXIST "%%G\info.txt" ( if EXIST "%%G\.svn\*" (
	ECHO.
	ECHO Updating %%G
	svn up "%%G"
) ) )
GOTO end

:tortoise
FOR /D %%G IN (garrysmod\garrysmod\addons\*) DO ( if EXIST "%%G\info.txt" ( if EXIST "%%G\.svn\*" (
	ECHO.
	ECHO Updating %%G
	TortoiseProc.exe /command:update /path:"%%G" /closeonend:1
) ) )
FOR /D %%G IN (garrysmod\garrysmod\gamemodes\*) DO ( if EXIST "%%G\info.txt" ( if EXIST "%%G\.svn\*" (
	ECHO.
	ECHO Updating %%G
	TortoiseProc.exe /command:update /path:"%%G" /closeonend:1
) ) )
GOTO end

:end

I am so very awesome

Of course a completely automated one is to prefer... like so:

CD C:\Program Files\Steam\steamapps\[username]
FOR /D %%G IN (garrysmod\garrysmod\addons\*) DO ( if EXIST "%%G\info.txt" ( if EXIST "%%G\.svn\*" ( svn up "%%G" ) ) )
FOR /D %%G IN (garrysmod\garrysmod\gamemodes\*) DO ( if EXIST "%%G\info.txt" ( if EXIST "%%G\.svn\*" ( svn up "%%G" ) ) )