Digital Screen Scanner (Colour w/ hitNormal)

[Dingo2]

Pictures:
This is a picture of what the exact code below can make (On the left obviously. It cant make those props )


Below is a picture of the same set of props but with a code rewrite to make it work for a 512x512 screen


Description:
This code will use ranger functions to plot pixels on a digital screen (128x128) depending on the props infront of the E2 chip. So in effect its a scanner of props that then shows what they look like on a digital screen.

Set-up:
1. Create a digital screen with the Height and Width set to 128.
2. Spawn the E2 chip on your choice of prop, or on the ground OR on the screen. It doesnt matter
3: Get out the "Expression 2 - Wirelink" tool In Wire - Tools and left click on the digital screen with it
4. Get out the Wire tool and wire the Ds [WIRELINK] input on the E2 to the digital screen's link [WIRELINK] output
5. Place whatever you put the E2 chip on such that the E2 chip faces a contraption/prop/whatever
6. Press E or whatever you have the Use key bound to and the scan will commence
7. ENJOY YOUR PICTURE

@name Digital Scanner Colour (Dingo)
@inputs Ds:wirelink
@persist Y Range E:entity O:entity

interval(100)       #Increase if hard quota is exceeded

if(first() | changed(Ds)){ 
    Range = 500     #Set the range of the Ranger trace here
    Ds[1048569]=3   #Changes Number Format to RRRGGGBBB
    E = entity()
    Y = 129
    O = owner()
}

if(O:keyUse()){
    Ds[1048574]=1   #Clears Digital Screen
    Y = 0           #Reset Y Value
}
    
    for(X = 0,128){ #Loop code from X = 0 to X = 128
        if(Y>128){
            exit()      #When done stop the for loop until reset
        }
    Ranger = ranger(Range,(X-64)/64,(Y-64)/64)                              #Set up Ranger with X Y skew
    LDir = (E:pos()-Ranger:position()):normalized()                         #Find the Light Direction
    DistSc = (Range - Ranger:distance())/Range                               #Generate a variable between 0 and 1 to darken into the distance
    Shade = Ranger:entity():getColor()*DistSc*LDir:dot(Ranger:hitNormal())  #Get the Shaded Colour of the pixel
    Clr = rgb2digi(Shade,3)                                                 #Turn Shade into the correct format
    Ds[X+ Y*128]= Clr                                                       #Plot pixel
}

Y++   #Goto next line

Other Details:
The Light Direction is currently from the E2 chip. I may change this at some point :mellow:

If you're exceeding the hard quota increase the interval
You can change the range of the scan where it says so in the code
Try not to mess with the other lines unless you know what you're doing ^_^

The code uses a ranger trace so it'll show what the props hitbox looks like which is not always exactly what see when you look at the prop, as you can see with the breen globe above.

PS:
I would appreciate any help with optimization. Thanks in advance


[EDIT]: Newer, messier, less optimised, slower code. It now has Shadows, light sources and NO alpha blending since I killed it somehow

@name Digital Scanner Colour (Dingo)
@inputs Ds:wirelink
@persist Y Range E:entity O:entity LightA:array LCount Mul

interval(100)

if(first() | changed(Ds)){ 
    Range = 1500
    Ds[1048569]=3
    E = entity()
    Y = 129
    O = owner()
    findIncludePlayerProps(O)
}

if(O:keyUse()){
    Ds[1048574]=1
    Y = 0
    findByModel("models/hunter/misc/sphere025x025.mdl")
    LightA = findToArray()
    LCount = LightA:count()
}
    
    for(X = Mul*64,(Mul+1)*64){ #Loop code from X = 0 to X = 128
        if(Y>128){
            exit()
        }
    Ranger = ranger(Range,(X-64)/128,(int(Y)-64)/128)
    Ent = Ranger:entity()
    TotL = 0
    TotS = 0
    Dist = Ranger:distance()
    Pos = Ranger:position()
    
    if(LCount){
    for(I = 1,LCount){
        LDir = (LightA:entity(I):pos() - Pos):normalized()
        TotL += abs(LDir:dot(Ranger:hitNormal()))
        
        rangerFilter(LightA)
        rangerFilter(Ent)
        LRanger = rangerOffset(LightA:entity(I):pos(),Pos)
        TotS += (LRanger:hit() ? 0.8 : 1 )
        if( I == LCount){
            AvgL = TotL/LCount
            AvgS = TotS/LCount
    }
    }
    }
    
    DistSc = -(Dist/Range)+1
    
    if(Ent:type():find("player")){FColor = (Ent:getColor() == vec(255,255,255)) ? teamColor(Ent:team()) : Ent:getColor()}
    elseif(!Ent:type():find("_") & Ranger:hit()){FColor = vec(0,255,0)}                            
    else{FColor = Ranger:entity():getColor()}
    
    Shade = FColor*DistSc*AvgL*AvgS
    DsColor = rgb2digi(Shade,3)
    Ds[X+ int(Y)*128]= DsColor
}
Mul = (Mul == 1 ? 0 : 1)
Y+=0.5

[goluch]

Wow this is the first scanner i have seen with 3d color.

[Unsmart]

Yeah, but with the fact that its in color, your kinda loosing the distance perspective. But its cool.
+rep

[Dingo2]

The screen does darken the colours to black the further away the point the ranger trace hits. At least it should be, I'd say its because the props are quite close and the range is to big for the darkening to kick in much

[Unsmart]

The screen does darken the colours to black the further away the point the ranger trace hits. At least it should be, I'd say its because the props are quite close and the range is to big for the darkening to kick in much

I get your point, you have some equations in there. I see that, but lets say we got a prop with color=[3,3,3], and 100 units away. on a normal screen you would see it quite white, but how would it look on yours?

Still good job.

[GUN]

i have a fix for the tick quota,

@name Digital Scanner Colour (Dingo)
@inputs Ds:wirelink
@persist Y Range E:entity O:entity

interval(100)       #Increase if hard quota is exceeded

if(first() | changed(Ds)){ 
    Range = 500     #Set the range of the Ranger trace here
    Ds[1048569]=3   #Changes Number Format to RRRGGGBBB
    E = entity()
    Y = 129
    O = owner()
}

if(O:keyUse()){
    Ds[1048574]=1   #Clears Digital Screen
    Y = 0           #Reset Y Value
}
    X=0
    while(X <,128){ #Loop code from X = 0 to X = 128
    if (ops()>maxquota()-1000|ops()>minquota()-1000 ) {continue} 
        if(Y>128){
            exit()      #When done stop the for loop until reset
        }
    Ranger = ranger(Range,(X-64)/64,(Y-64)/64)                              #Set up Ranger with X Y skew
    LDir = (E:pos()-Ranger:position()):normalized()                         #Find the Light Direction
   DistSc = (Range - Ranger:distance())/Range                               #Generate a variable between 0 and 1 to darken into the distance
    Shade = Ranger:entity():getColor()*DistSc*LDir:dot(Ranger:hitNormal())  #Get the Shaded Colour of the pixel
    Clr = rgb2digi(Shade,3)                                                 #Turn Shade into the correct format
    Ds[X+ Y*128]= Clr  
    X++                                                     #Plot pixel
}

Y++   #Goto next line

useing a while loop and

if (ops()>maxquota()-1000|ops()>minquota()-1000 ) {continue}

will make it so if the loop gets close to the tick quota, itl skip the code for 1 cycle and resume on the next, if its still within the orange area, itl skip again, but it will do so very fast and i have yet to get it to the hard quota

[Dingo2]

Looking at that I'd say it would still add one to the Y value and therefore skip the rest of the digital screen line? [EDIT] Nvm I see it says continue now
Regardless I'll put something similar in. Thankyou

[EDIT2] Well for some reason if I use what you've got there, it exceeds the quota instantly and with a for loop it takes a a little bit but it still exceeded ...
Not sure whats going on

[Magos Mechanicus]

useing a while loop and

if (ops()>maxquota()-1000|ops()>minquota()-1000 ) {continue}

will make it so if the loop gets close to the tick quota, itl skip the code for 1 cycle and resume on the next, if its still within the orange area, itl skip again, but it will do so very fast and i have yet to get it to the hard quota

I wonder why noone ever reads the docs on this. minquota() and maxquota() return how much is left of their respective quota, not the absolute size of the quota. Correct usage is to exit your loops if these functions get lower than a constant. Ideally the constant should be slightly more than the quota cost of one loop execution.

Edit: To illustrate, compare

@persist A

runOnTick(1)
while(1){A++
    if (minquota() < 150) {break} 
    }

and

@persist A

runOnTick(1)
while(1){A++
    if (ops()>maxquota()-1000|ops()>minquota()-1000 ) {break} 
    }

The former stabilizes at 97% usage of the E2's capabilities, while the latter stops at a mere 40% (with default quotas).

[Solece]

Why use 97% when you can perfectly run at 100%?

while(opcounter()<5000){A++}

I've always used this method and it runs perfectly at 100%.

[Magos Mechanicus]

Because 5000 won't be the softquota for all servers at all times?