[E2 Help] Entity -> Direction Vector

[Alchemise]

Hi

Just making a simple follower drone at the moment, it hovers just above a player; aims a turret etc. I'm trying to make as much of my contraption built onto the one chip as possible.

I have the vertical stablization and direction thrusters sorted, using the applyForce(V) function; but I haven't managed to implement the rotational stablization.

I had in mind to use the applyOffsetForce(V, V) function twice, to replace two thrusters which are a set distance from the centre, and are angled perpendicular to the device so as to develop torque.

Two problems with this. Firstly, the direction vector for the force. I can't work out how to acquire the direction vector of an entity. Its something to do with E:toWorld(V), but I'm not sure. Once I have the direction of the entity (the chip itself), I can then simply rotate it 90 degrees in the yaw axis. That way it will always point perpendicular to the entity.

Second problem is the position vector. I need to find the coords of a point just in front of and behind the chip; that changes relatively. This could be done by welding a gps to where I need the coords, but this defies the whole single chip ethos. The only way I can think of doing it is with an entity marker and little prop welded on to the device, or a gps.



Any help would be greatly appreciated.

Oh, and by the way - is it possible to capture chat text as a string? I'm thinking typing a target's name into chat and it running off to kill it.

[Magos Mechanicus]

You know, entities don't have one direction vector but rather 3 of them. They are forward, right and up, and the corresponding E2 functions are E:forward()/right()/up(). They return unit vectors in the world coordinate system that point in the appropriate direction at the time the function is run. For instance, the points you have marked out might be something like this:

E:pos()+10*E:forward() and E:pos()-10*E:forward()

.
toWorld() is indeed quite useful as a shorthand for stuff you want to define locally, though. The way it works is that

E:toWorld(vec(X,Y,Z)) = E:pos() + X*E:forward() + Y*E:right() + Z*E:up()

Combining those two, for that rotation there you could for instance do

V=vec(10,0,0) Force=100*Ent:right()*Ent:mass()
Ent:applyOffsetForce(Ent:toWorld(V),Force)
Ent:applyOffsetForce(Ent:toWorld(-V),-Force)

The 10 in V and the 100 in Force are fiddlable constants that can be useful for adjusting to stuff that's very large or whatever - multiplying the force by the mass of the entity helps make its effects consistent.

[Alchemise]

Thanks for those lines, they get me the vectors I wanted. Makes perfect sense, shame I didn't think of it. [Pos] + k*[Dir]

Although, at the moment I see to be having an entity problem.

My design is a phx disk, with a small arm connected to hyrdualics to be the turret mount. I was using the entity marker jobby on the arm itself so I could get the elevation to the target.

Whenever I dupe my design, the entity marker dies and the program gets stuck trying to do operations on a null entity. It locks up the chip, and I can't wire anything to it. Sometimes rewiring works, but most of the time it doesn't.

Is there any other way of getting entity info from a prop? Or is there a way of solving the lockup issues?

[Alchemise]

Okay, its a new bug. The old code still works fine when rewired. I can wire the old one, and update the chip with the new code and still get this error message:

Timer Error: entites\gmod_wire_expression2\core\entity.lua.352: attempt to index global 'entity' (a nil value)

Anyone got any idea what the error means, or what it is caused by?

I've included my code if you think you can work it out from there. Arm is the entity marker input, Flip and Fire are user inputs to toggle the drone and its weapons. Scan is linked to the Flip input, and just scans for the target (me)

@name follower
@inputs Scan Flip Fire Arm:entity
@outputs Guns Hyd
@persist ForVec:vector ThrPosF:vector Arm:entity ThrPosB:vector ThrDir:vector Tr X DZ F D DX DY QX QY ArmPi AngArm:angle Pos:vector TPos:vector DThrust:vector Self:entity Target:entity
interval(10)
############################
#Follower Drone by Alchemise
############################
############################
#Vertical Stabilzation
############################

Self = entity()
Pos = Self:pos()
QZ = TPos:z()
DZ = Pos:z()
T = 30*(420 - Pos:z()) - 50*$DZ

############################
#Target Finding
############################

if(Scan == 1){
findInSphere(Pos, 100000)
findClipToName("Alchemise")
Target = find()
}

############################
#Movement
############################

TPos = Target:pos()
D = Pos:distance(TPos)
DX = TPos:x() - Pos:x()
DY = TPos:y() - Pos:y()
QX = Pos:x()
QY = Pos:y()
QZ = Pos:z()
if(D < 500){
DThrust = vec(-200*$QX*Flip, -200*$QY*Flip, T*Flip)}
else{
DThrust = vec(Flip*DX, Flip*DY, Flip*T)}
applyForce(DThrust)

############################
#Rotation & Arm Pitch
############################

AngArm = Arm:angles()
ArmPi = Arm:elevation(TPos)
if(ArmPi > 0){Hyd += 0.4}
if(ArmPi < 0){Hyd -= 0.4}
Hyd = clamp(Hyd, 2, 55)
if(Flip == 0){Hyd = 2}
else{Hyd = Hyd}
X = Self:bearing(TPos)
Tr = ((0.5*X + 2*$X)*-0.3*Flip)
if((abs(ArmPi) < 5) & (abs(X) < 5) & (Fire == 1)){
Guns = 1}
else{Guns = 0}
ForVec = Self:forward()
ThrPosF = Pos + 2*ForVec
ThrPosB = Pos - 2*ForVec
ThrDir = Self:right()

applyOffsetForce(Tr*ThrDir, ThrPosF)
applyOffsetForce(-Tr*ThrDir, ThrPosB)

[ZeikJT]

Okay, its a new bug. The old code still works fine when rewired. I can wire the old one, and update the chip with the new code and still get this error message:

Timer Error: entites\gmod_wire_expression2\core\entity.lua.352: attempt to index global 'entity' (a nil value)

Anyone got any idea what the error means, or what it is caused by?

You must have an older version of the SVN. I checked line 352, it doesn't have any entity defined anywhere near there.
If you still have problems after updating post again.

[Magos Mechanicus]

One alternative to the entity marker is to use the find extension. Most of the time this is for applications that always operate on the same entity, so you usually only have to run it once. My method is to first find the model name of my prop (right click in the spawn menu, there is a copy to clipboard option) and then do:

@persist Arm:entity
if(!Arm){findIncludeModel("Modelname here")
findInSphere(entity():pos(),300)
Arm=findClosest(entity():pos())
findDisallowModel("Modelname here")}

The last line isn't usually necessary for me, but since you use the find extension for target aquisition it's probably best to make sure your whitelist is clean.

[Alchemise]

I would have be cussing for hours trying to get it to work. Yea, my svn was out of date. Damn you all for updating it so often =)

The newer version of entity marker is a lot more stable, and doesn't churn out errors. Before when I duped my drone all the chips flew off the top.

It works beautifully now.

No I jsut need to come up with some code to switch targets etc. Maybe add some other uses. I'm thinking if come up with a practical find black/white list I could get it to find certain props, maybe even use a grabber on them.

Anyways, thanks for the help guys.

[|Voodoo|]

This look like an old dupe I have (did not make it) but since the change over to Ep2, it has not worked quite right.